前準備

　初めに、Google Developer Console から、アプリケーションの登録を行います。登録手順の詳細などは以下のリンクを参考に。ここでは、新しいクライアント ID を生成する際に、"インストールされているアプリケーション"を選択して、クライアント ID、クライアント シークレット、リダイレクト URI の3つのパラメータを控えておきます。

• 初心者でも分かる！なGoogle Analytics APIの使い方
• Google API の OAuth2 認証で Refresh token を取得するには - talk to oneself 2
• [PHP] Google Analytics API v3.0 を使って解析データを取得する | unlinked log
• Google Analytics API v3をPHPから利用する方法 | karakaram-blog

Step 1. アプリケーションの認証と認証コードの取得

　下記のコードを実行すると、https://accounts.google.com/o/oauth2/auth?... から始まる URL が表示されるので、URL 文字列をコピーして Web ブラウザで開きます。Google アカウントでログインすると、このアプリケーションが Google Analytics のデータを表示しても良いか尋ねてくるので承認します。

### Developer Console から控えておいたクライアント ID、クライアント シークレット、リダイレクト URI
my %client = (
    client_id =>        '123456789012-xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx.apps.googleusercontent.com',
    client_secret =>    'HogeFugaPiyoHogeFugaPiyo',
    redirect_uri =>     'urn:ietf:wg:oauth:2.0:oob',
);

use URI::Escape;
my %param = (
    response_type =>    'code',
    client_id =>        $client{client_id},
    redirect_uri =>     $client{redirect_uri},
    # @see https://developers.google.com/analytics/devguides/config/mgmt/v3/mgmtAuthorization
    scope =>            'https://www.googleapis.com/auth/analytics.readonly',
);
my $url = 'https://accounts.google.com/o/oauth2/auth?'. # auth_uri
    join '&', map { uri_escape($_). '='. uri_escape($param{$_}) } keys %param;
print $url;

　承認すると、次のような画面に切り替わるので、認証コードをコピーして次に進みます。

Fig.1 認証コードのコピー

• Forming the URL for an authentication request

Step 2. refresh_token を得る

　Step 1. で取得した認証コードを使ってトークンを取得します。

### ここは step1.pl と同じ
my %client = ( ... );

use LWP::UserAgent;
my %param = (
    code =>             'AUTHENTICATION_CODE', # Step 1. で取得した認証コード
    client_id =>        $client{client_id},
    client_secret =>    $client{client_secret},
    redirect_uri =>     $client{redirect_uri},
    grant_type =>       'authorization_code',
);
my $ua = LWP::UserAgent->new or die;
my $res = $ua->post( # POST
    'https://accounts.google.com/o/oauth2/token', # token_uri
    \%param
) or die;
$res->is_success or die $res->status_line;
print $res->content;

　リクエストが成功すると、次のような JSON データが返ってきます。

{
  "access_token" : "XXXXXXXX_ACCESS_TOKEN_XXXXXXXX",
  "token_type" : "Bearer",
  "expires_in" : 3600,
  "refresh_token" : "XXXXXXXX_REFRESH_TOKEN_XXXXXXXX"
}

　Step 1. で取得した AUTHENTICATION_CODE は、上記のスクリプトを実行するたびに失効するので、実験などでトークンを度々取得するには、その都度、認証コードを取得しなければなりません。

• Handling the response and making a token request

Step 3. access_token を得る

　Google API にアクセスする時には、この access_token が必要になりますが、expires_in で示された期限後(単位は秒)には有効期限が切れてしまいます。そこで、refresh_token を利用して access_token を取得しなおします。

### ここは step1.pl と同じ
my %client = ( ... );

use LWP::UserAgent;
my %param = (
    refresh_token =>    'XXXXXXXX_REFRESH_TOKEN_XXXXXXXX',
    client_id =>        $client{client_id},
    client_secret =>    $client{client_secret},
    grant_type =>       'refresh_token',
);
my $ua = LWP::UserAgent->new or die;
my $res = $ua->post(
    'https://accounts.google.com/o/oauth2/token', # token_uri
    \%param
) or die;
$res->is_success or die $res->status_line;
print $res->content;

　リクエストが成功すると、次のような JSON データが返ってきます。

{
  "access_token" : "XXXXXXXX_NEW_ACCESS_TOKEN_XXXXXXXX",
  "token_type" : "Bearer",
  "expires_in" : 3600,
}

Step 4. Google API を叩いてみる

　例えば、Google Analytics で使える API から、ウェブサイトの Page View 数を取得するには、先ほど取得した access_token をくっ付けて、次のような URL にアクセスします^*1。

https://www.googleapis.com/analytics/v3/data/ga?ids=ga%3A3857126&start-date=2015-05-01&end-date=2015-05-31&metrics=ga%3Apageviews&access_token=XXXXXXXX_ACCESS_TOKEN_XXXXXXXX

　試しに、めちゃくちゃな access_token に書き換えてみると、エラーが返ってくるのが判ります。

まとめ

1. Google API を利用するには access_token を付けてリクエストを行う
2. refresh_token を用いて access_token を取得できる
3. refresh_token は何度でも/いつまでも使える
4. アプリケーションのセットアップ時に Step1. と Step2. の手順から refresh_token を取得して設定ファイルなどに書き出しておけば、以降は access_token を簡単に取得できる
5. 公開カレンダーやブログ、Google マップや Google 翻訳など、Oauth 認証を必要としないデータへのアクセスには、"API キー" を使うとのこと 参考
6. 超ざっくり云うと、OAuth 2.0 では 1) HTTPS 通信が必須になって、2) ややこしい署名が不要に